*  JieJie Microelectronics P-Spice Model Library
*  Filename	: JMSL1009AG_P v.20220808.txt
*  Product Name   :  JMSL1009AG (PDFN5x6-8L)
*  Configuration:	: Single N channel Device
*  Data Sheet Rev.	: 1.0
*  Release Date	: Aug8, 2022
*  Junction Temp (Tj): -40C ~ 150C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMSL1009AG D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
Vmonitor D 18 0
RD 18 1 0.007
RS S 3 1E-009
RG G 17 1.6
CGS 3 G 1.28E-9
EGD 12 0 2 1 1
Etemp 17 2 VALUE = {(-0.00312*(TEMP-25))+((-2.76224E-6)*(TEMP-25)^2)}
Gtemp 1 3 VALUE = {I(Vmonitor)*((TEMP+273)/(298)-((TEMP+273)/(298))^2.8)}

VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 5.5E-10
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
Cbreak D 3 Cbreak  1.47113E-9
.MODEL Cbreak CAP (C = 1  VC1 = -0.01741   VC2 = 8.68664E-5）

.model NMOS NMOS
+LEVEL = 3                     VMAX = 1E9                    ETA = 1E-4   
+VTO = 1.638161                  TOX = 8E-10                   NSUB = 1E22    
+KP = 420.323904                  U0 = 200                      KAPPA = 0.1     
+GAMMA = 0.2302                PHI = 0.599536                THETA = 0.234494  
+DELTA = 289.998854      

.model DCGD D
+CJO = 3.5E-10                 VJ = 14                       M = 1.7   

.model DSUB D
+IS = 2.625E-12                N = 1.039896                  RS = 2.924E-3  
+BV = 107.4                 xti = -1.86   

.model DLIM D
+IS = 1E-4   
.ends JMSL1009AG

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************

